# Maintainer: Michael Walker <mike@barrucadu.co.uk>

pkgbase=uzbl
pkgname=('uzbl-core' 'uzbl-browser' 'uzbl-tabbed')
pkgver=2010.08.05
pkgrel=1
arch=('i686')
url="http://www.uzbl.org"
license=('GPL3')
makedepends=('libwebkit>=1.2.0')
source=(uzbl-$pkgver.tar.gz::http://github.com/Dieterbe/uzbl/tarball/$pkgver)
md5sums=('b6e3323337d2093e55c7d85648bab3aa')

build() {
    cd "$srcdir"/Dieterbe-uzbl-*
    make
}

package_uzbl-core() {
   pkgdesc="Webpage interface component meant for integration with other tools and scripts"
   depends=('libwebkit')
   optdepends=('socat: to interface with the socket'
               'dmenu: to run some of the example scripts'
               'zenity: to run some of the example scripts'
               'python: to run some of the example scripts'
               'xclip: for clipboard related keybindings'
	       'pygtk: for uzbl-tabbed')

   cd "$srcdir"/Dieterbe-uzbl-*
   make DESTDIR="$pkgdir" PREFIX=  install-uzbl-core
}

package_uzbl-browser() {
   pkgdesc="A complete browser experience based on uzbl-core"
   depends=("uzbl-core=$pkgver" 'socat' 'zenity' 'xclip' 'dmenu' 'python')
   cd "$srcdir"/Dieterbe-uzbl-*
   make DESTDIR="$pkgdir" PREFIX=  install-uzbl-browser
}

package_uzbl-tabbed() {
   pkgdesc="Tabbing manager providing multiple uzbl-browser instances in 1 window"
   depends=("uzbl-browser=$pkgver" 'pygtk')
   cd "$srcdir"/Dieterbe-uzbl-*
   make DESTDIR="$pkgdir" PREFIX= install-uzbl-tabbed
}